win10专业版 - 提供最新win10专业版系统下载
首页
win10专业版 win10纯净版 win10 ghost win10密钥 win10激活工具 win10安装教程
当前位置:首页 > win10安装教程 > win10怎么为批处理文件自动添加管理员权限

win10怎么为批处理文件自动添加管理员权限

时间:2019-01-05 09:27:44     来源:win10专业版     游览量: 153 次

  一般在进行批处理文件的运行中,是需要使用到管理员权限才可以正常的运行和操作使用的,但是有的用户表示每次使用都需要添加管理员权限,操作起来很麻烦,用户表示需要直接自动添加管理员权限的设置,那么win10怎么为批处理文件自动添加管理员权限呢?

win10怎么为批处理文件自动添加管理员权限

  1、桌面新建记事本,复制以下代码。

:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

::     自动添加批处理文件管理员权限      ::

:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

@echo off

CLS

ECHO.

ECHO ================================

ECHO 获取批处理文件管理员权限

ECHO ================================

:init

setlocal DisableDelayedExpansion

set "batchPath=%~0"

for %%k in (%0) do set batchName=%%~nk

set "vbsGetPrivileges=%temp%\OEgetPriv_%batchName%.vbs"

setlocal EnableDelayedExpansion

:checkPrivileges

NET FILE 1>NUL 2>NUL

if '%errorlevel%' == '0' ( goto gotPrivileges ) else ( goto getPrivileges )

:getPrivileges

if '%1'=='ELEV' (echo ELEV & shift /1 & goto gotPrivileges)

ECHO.

ECHO ********************************

ECHO 请求 UAC 权限批准……

ECHO ********************************

ECHO Set UAC = CreateObject^("Shell.Application"^) > "%vbsGetPrivileges%"

ECHO args = "ELEV " >> "%vbsGetPrivileges%"

ECHO For Each strArg in WScript.Arguments >> "%vbsGetPrivileges%"

ECHO args = args ^& strArg ^& " "  >> "%vbsGetPrivileges%"

ECHO Next >> "%vbsGetPrivileges%"

ECHO UAC.ShellExecute "!batchPath!", args, "", "runas", 1 >> "%vbsGetPrivileges%"

"%SystemRoot%\System32\WScript.exe" "%vbsGetPrivileges%" %*

exit /B

:gotPrivileges

setlocal & pushd .

cd /d %~dp0

if '%1'=='ELEV' (del "%vbsGetPrivileges%" 1>nul 2>nul  &  shift /1)

:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

::     以下为需要运行的批处理文件代码     ::

:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

rem 本行以下可修改为你需要的bat命令(从上面三行冒号开始到下面都可删改)

ECHO 欢迎使用!

ECHO.

pause

  2、win10怎么为批处理文件自动添加管理员权限?另存为.bat文件,双击运行,提示添加成功,运行批处理文件,确定。

 

  完成之后就可以正常的进行批处理文件的一些设置和操作,不会出现使用的时候提示有存在需要管理员权限的情况,如果用户不知道win10怎么为批处理文件自动添加管理员权限,需要进行代码的输入到记事本中,另存为.bat文件进行运行获取管理员权限。

本文来自win10专业版 http://www.win10zhuanyeban.com 如需转载请注明!

返回网站首页
0
win10纯净版排行
win10安装教程